C
C Program SMGM to compute product GM2=SM1*GM1 of symmetric matrix SM1
C and general matrix GM1.
C
C Version: 5.50
C Date: 2001, May 14
C
C Coded by Petr Bulant
C     Department of Geophysics, Charles University Prague,
C     Ke Karlovu 3, 121 16 Praha 2, Czech Republic,
C     E-mail: bulant@seis.karlov.mff.cuni.cz
C
C.......................................................................
C                                                    
C Description of data files:
C
C Input data read from the standard input device (*):
C     The data are read by the list directed input (free format) and
C     consist of a single string 'SEP':
C     'SEP'...String in apostrophes containing the name of the input
C             SEP parameter or history file with the input data.
C     No default, 'SEP' must be specified and cannot be blank.
C
C                                                     
C Input data file 'SEP':
C     File 'SEP' has the form of the SEP
C     parameter file.  The parameters, which do not differ from their
C     defaults, need not be specified in file 'SEP'.
C Data specifying dimensions of the matrices:
C     M1='string'... Name of the file containing a single integer number
C             specifying the number of rows and columns of matrix SM1
C             and rows of matrices GM1 and GM2.
C             Default: M1=' ' means that the number is 1.
C     M2='string'... Name of the file containing a single integer number
C             specifying the number of columns of matrices GM1 and GM2.
C             Default: M2=' ' means that the number is 1.
C Filenames of the files with the matrices:
C     SM1='string' ... Name of the input file containing matrix SM1.
C             No default, 'SM1' must be specified and cannot be blank.
C     GM1='string' ... Name of the input file containing matrix GM1.
C             No default, 'GM1' must be specified and cannot be blank.
C     GM2='string' ... Name of the file containing matrix GM2 (output).
C             No default, 'GM2' must be specified and cannot be blank.
C     For general description of the files with matrices refer to file
C     forms.htm.
C Form of the files with matrices:
C     FORMM='string' ... Form of the files with matrices. Allowed values
C             are FORMM='formatted' and FORMM='unformatted'. If the form
C             differs for input and for output files, FORMMR and FORMMW
C             should be used instead of FORMM.
C             Default: FORMM='formatted'
C     FORMMR='string' ... Form of the files with matrices to be read.
C             Default: FORMMR=FORMM
C     FORMMW='string' ... Form of the files with matrices to be written.
C             Default: FORMMW=FORMM
C
C-----------------------------------------------------------------------
C Subroutines and external functions required:
      EXTERNAL ERROR,RSEP1,RSEP3T,RMAT,WMAT
C     ERROR ... File error.for.
C     RSEP1,RSEP3T ... File sep.for.
C     RMAT,WMAT ... File forms.for.
C
C Common block /RAMC/:
      INCLUDE 'ram.inc'
C     ram.inc
C
      CHARACTER*80 FILSEP,FILE1,FILE2,FILE3
      INTEGER M1,M2,NA,NB,LU1,I1,I2,I3,J1,J2,J3
      REAL CIJ
      PARAMETER (LU1=1)
C-----------------------------------------------------------------------
C
C     Reading a name of the file with the input data:
      WRITE(*,'(A)') '+SMGM: Enter input filename: '
      FILSEP=' '
      READ(*,*) FILSEP
C
C     Reading all the data from the SEP file into the memory:
      IF (FILSEP.NE.' ') THEN
        CALL RSEP1(LU1,FILSEP)
      ELSE
C       SMGM-01
        CALL ERROR('SMGM-01: SEP file not given')
      ENDIF
C
C     Reading the dimensions of the matrices:
      CALL RSEP3T('M1',FILE1,' ')
      IF (FILE1.EQ.' ') THEN
        M1=1
      ELSE
        OPEN(LU1,FILE=FILE1,STATUS='OLD')
        READ(LU1,*) M1
        CLOSE(LU1)
      ENDIF
      CALL RSEP3T('M2',FILE1,' ')
      IF (FILE1.EQ.' ') THEN
        M2=1
      ELSE
        OPEN(LU1,FILE=FILE1,STATUS='OLD')
        READ(LU1,*) M2
        CLOSE(LU1)
      ENDIF
      NA=M1*(M1+1)/2
      NB=M1*M2
C
      IF (NA+NB+M1.GT.MRAM) THEN
C       SMGM-02
        CALL ERROR('SMGM-02: Small dimension MRAM of array RAM')
      ENDIF
C
C     Reading the names of the files with the matrices:
      CALL RSEP3T('SM1',FILE1,' ')
      CALL RSEP3T('GM1',FILE2,' ')
      CALL RSEP3T('GM2',FILE3,' ')
      IF (FILE1.EQ.' ') THEN
C       SMGM-03
        CALL ERROR('SMGM-03: Input file with matrix SM1 not given.')
      ENDIF
      IF (FILE2.EQ.' ') THEN
C       SMGM-04
        CALL ERROR('SMGM-04: Input file with matrix GM1 not given.')
      ENDIF
      IF (FILE3.EQ.' ') THEN
C       SMGM-05
        CALL ERROR('SMGM-05: Output file with matrix GM2 not given.')
      ENDIF
C
C     Reading input matrices:
      CALL RMAT(LU1,FILE1,M1,0,RAM)
      CALL RMAT(LU1,FILE2,M1,M2,RAM(NA+1))
C
      WRITE(*,'(A)') '+SMGM: Working...            '
C
C     Multiplication:
C     Loop over columns:
      DO 10, I1=1,M2
        J3=NA+NB
C       Loop over rows:
        DO 20, I2=1,M1
          CIJ=0.
          J2=NA+M1*(I1-1)
          DO 30, I3=1,M1
C           Element of the first matrix:
            IF (I3.LE.I2) THEN
              J1=I2*(I2-1)/2+I3
            ELSE
              J1=I3*(I3-1)/2+I2
            ENDIF
C           Element of the second matrix:
            J2=J2+1
            CIJ=CIJ+RAM(J1)*RAM(J2)
  30      CONTINUE
          J3=J3+1
          RAM(J3)=CIJ
  20    CONTINUE
        J2=NA+M1*(I1-1)
        J3=NA+NB
C       Loop over rows of the I1th column
        DO 21, I2=1,M1
          J2=J2+1
          J3=J3+1
          RAM(J2)=RAM(J3)
  21    CONTINUE
  10  CONTINUE
C
C     Writing output matrix:
      CALL WMAT(LU1,FILE3,M1,M2,RAM(NA+1))
      WRITE(*,'(A)') '+SMGM: Done.                 '
C
      STOP
      END
C
C=======================================================================
C
      INCLUDE 'error.for'
C     error.for
      INCLUDE 'sep.for'
C     sep.for
      INCLUDE 'forms.for'
C     forms.for
      INCLUDE 'length.for'
C     length.for
C
C=======================================================================
C