C                                                            <HTML><PRE>
C Program SMPOWER to compute matrix SM2, which is POWER-th power of
C input symetric matrix SM1.
C
C Version: 6.20
C Date: 2008, June 12
C
C Coded by Petr Bulant
C     Department of Geophysics, Charles University Prague,
C     Ke Karlovu 3, 121 16 Praha 2, Czech Republic,
C
C.......................................................................
C                                                    <A NAME="data"></A>
C Description of data files:
C
C Input data read from the standard input device (*):
C     The data are read by the list directed input (free format) and
C     consist of a single string 'SEP':
C     'SEP'...String in apostrophes containing the name of the input
C             SEP parameter or history file with the input data.
C     No default, 'SEP' must be specified and cannot be blank.
C
C                                                     <A NAME="SEP"></A>
C Input data file 'SEP':
C     File 'SEP' has the form of the <A HREF="../forms/sep.htm">SEP</A>
C     parameter file.  The parameters, which do not differ from their
C     defaults, need not be specified in file 'SEP'.
C Data specifying dimensions of the matrices:
C     M1='string'... Name of the file containing a single integer number
C             specifying the number of rows (and columns) of symmetric
C             matrices A and R.
C             Default: M1=' ' means that the number is 1.
C Filenames of the matrix header files:
C     SM1='string' ... Name of the header file of the symmetric
C             matrix SM1.
C             No default, 'SM1' must be specified and cannot be blank.
C     SM2='string' ... Name of the header file of the symmetric
C             matrix SM2=SM1**POWER.
C             No default, 'SM2' must be specified and cannot be blank.
C     Recent version of the program cannot deal with sparse matrices.
C     For general description of the files with matrices refer to file
C     <A HREF="../forms/forms.htm#MAT">forms.htm</A>.
C Form of the output data file with matrix SM1:
C     FORMM='string' ... Form of the output files with matrices. Allowed
C             values are FORMM='formatted' and FORMM='unformatted'.
C Data specifying the power:
C     POWER=real ... Power of the matrix SM1.
C             Default: POWER=1.
C
C-----------------------------------------------------------------------
C Subroutines and external functions required:
      EXTERNAL SMBLO,SMPOW,IND,ERROR,RSEP1,RSEP3T,RSEP3R,RMAT,WMAT,EIGEN
      INTEGER IND
C     SMBLO,SMPOW,IND ... This file.
C     ERROR ... File <A HREF="error.for" TYPE="text/html">error.for</A>.
C     RSEP1,RSEP3T,RSEP3R ...
C             File <A HREF="sep.for" TYPE="text/html">sep.for</A>.
C     RMAT,WMAT ... File
C     <A HREF="mat.for" TYPE="text/html">mat.for</A>.
C     EIGEN ... <A HREF="eigennr.for" TYPE="text/html">eigennr.for</A>.
C
C Common block /RAMC/:
      INCLUDE 'ram.inc'
C     <A HREF="ram.inc" TYPE="text/html">ram.inc</A>
      INTEGER IRAM(MRAM)
      EQUIVALENCE (IRAM,RAM)
C
      CHARACTER*80 FILSEP,FILE1,FILE2
      INTEGER M1,N,NN,NB,LU1,I1,I2,I3,I4,IBMI,IBMA
      PARAMETER (LU1=1)
      REAL POWER
C
C-----------------------------------------------------------------------
C
C     Reading a name of the file with the input data:
      WRITE(*,'(A)') '+SMPOWER: Enter input filename: '
      FILSEP=' '
      READ(*,*) FILSEP
C
C     Reading all the data from the SEP file into the memory:
      IF (FILSEP.NE.' ') THEN
        CALL RSEP1(LU1,FILSEP)
      ELSE
C       <A NAME="error01"></A><FONT COLOR="RED">SMPOWER-01</FONT>
        CALL ERROR('SMPOWER-01: SEP file not given')
      ENDIF
C
C     Reading the dimension of the matrices:
      CALL RSEP3T('M1',FILE1,' ')
      IF (FILE1.EQ.' ') THEN
        M1=1
      ELSE
        OPEN(LU1,FILE=FILE1,STATUS='OLD')
        READ(LU1,*) M1
        CLOSE(LU1)
      ENDIF
      N=M1
      NN=M1*(M1+1)/2
      MAXRAM=MRAM-2*N
      IF (3*NN+N*N+N+N+1+N+N.GT.MRAM) THEN
C       <A NAME="error02"></A><FONT COLOR="RED">SMPOWER-02</FONT>
        CALL ERROR('SMPOWER-02: Small dimension MRAM of array RAM')
C       If possible, enlarge the dimension MRAM of array RAM in include
C       file <A HREF="ram.inc" TYPE="text/html">ram.inc</A>.
      ENDIF
C
C     Reading the names of the files with the matrices:
      CALL RSEP3T('SM1',FILE1,' ')
      CALL RSEP3T('SM2',FILE2,' ')
      IF (FILE1.EQ.' ') THEN
C       <A NAME="error03"></A><FONT COLOR="RED">SMPOWER-03</FONT>
        CALL ERROR('SMPOWER-03: Input file with matrix SM1 not given')
      ENDIF
      IF (FILE2.EQ.' ') THEN
C       <A NAME="error04"></A><FONT COLOR="RED">SMPOWER-04</FONT>
        CALL ERROR('SMPOWER-04: Output file with matrix SM2 not given')
      ENDIF
C
C     Reading input matrix:
      CALL RMAT(LU1,FILE1,M1,0,RAM(MAXRAM-NN+1))
C     Reading the power:
      CALL RSEP3R('POWER',POWER,1.)
C
      WRITE(*,'(A)') '+SMPOWER: Working...            '
C
C     Identification of blocks:
      CALL SMBLO(RAM(MAXRAM-NN+1),N,NN,NB,IRAM(MAXRAM-NN-N))
C
C     Preparing array for results:
      DO 5, I1=MAXRAM-2*NN-N,MAXRAM-NN-N-1
        RAM(I1)=0.
   5  CONTINUE
C
C     Computing the power:
      DO 20, I1=1,NB
C       Current block:
        IBMI=IRAM(MAXRAM-NN-N+I1-1)+1
        IBMA=IRAM(MAXRAM-NN-N+I1)
C       Moving the block to RAM(1):
        I4=0
        DO 10, I2=IBMI,IBMA
          DO 8, I3=IBMI,I2
            I4=I4+1
            RAM(I4)=RAM(MAXRAM-NN+IND(I3,I2))
   8      CONTINUE
  10    CONTINUE
        I2=IBMA-IBMI+1
        I3=I2*(I2+1)/2
C       Computing the power:
        CALL SMPOW(RAM,I2,I3,POWER)
C       Moving the block to RAM(MAXRAM-NN-N-1-NN+1):
        I4=0
        DO 14, I2=IBMI,IBMA
          DO 12, I3=IBMI,I2
            I4=I4+1
            RAM(MAXRAM-2*NN-N-1+IND(I3,I2))=RAM(I4)
  12      CONTINUE
  14    CONTINUE
  20  CONTINUE
C
C     Writing output matrix SM2:
      IF (FILE2.NE.' ') THEN
        CALL WMAT(LU1,FILE2,M1,0,RAM(MAXRAM-2*NN-N))
      ENDIF
      WRITE(*,'(A)') '+SMPOWER: Done.                 '
C
      STOP
      END
C
C=======================================================================
C
      SUBROUTINE SMPOW(SM,N,NN,POWER)
C
C=======================================================================
C     Computes the POWER-th power of symmetric matrix SM.
      INTEGER N,NN
      REAL SM(NN+N*N+N),POWER
C     Input: SM ... input symmetric matrix
C            N  ... number of rows (and columns) of the matrix
C            NN ... N*(N+1)/2
C            POWER ... the power
C     Output: SM ... the input matrix powered to POWER
      INTEGER I,J,I1,I2,I3
      REAL AUX,SMMAX
C-----------------------------------------------------------------------
      CALL EIGEN(SM,SM(NN+1),N,0)
      SMMAX=SM(1)
      DO 21 I=2,N
        SMMAX=AMAX1(SM(I*(I+1)/2),SMMAX)
   21 CONTINUE
      DO 22 I=1,N
        AUX=SM(I*(I+1)/2)
        IF(AUX.LE.0.) THEN
          IF(ABS(AUX).GT.0.000001*SMMAX
     *       .OR.(SMMAX.EQ.0..AND.POWER.LE.0.)) THEN
C           <A NAME="error05"></A><FONT COLOR="RED">SMPOWER-05</FONT>
            CALL ERROR('SMPOWER-05: Eigenvalue not positive')
          ENDIF
          IF(POWER.LE.0.) THEN
            AUX=0.000001*SMMAX
          ELSE
            AUX=0.
          END IF
        END IF
        SM(NN+N*N+I)=AUX**POWER
   22 CONTINUE
      DO 25 I=1,NN
        SM(I)=0.
   25 CONTINUE
      DO 28 I3=1,N
        AUX=SM(NN+N*N+I3)
        J=NN+N*(I3-1)
        I=0
        DO 27, I2=J+1,J+N
          DO 26, I1=J+1,I2
            I=I+1
            SM(I)=SM(I)+SM(I1)*SM(I2)*AUX
   26     CONTINUE
   27   CONTINUE
   28 CONTINUE
      RETURN
      END
C
C=======================================================================
C
      SUBROUTINE SMBLO(SM,N,NN,NB,IB)
C
C=======================================================================
C     Subroutine to find blocks of a symmetric matrix
      INTEGER N,NN,NB,IB(0:N)
      REAL SM(NN)
C     Input: SM ... symmetric matrix
C            N  ... number of rows (and columns) of the matrix
C            NN ... N*(N+1)/2
C     Output: NB ... number of blocks of the matrix
C             IB ... array with numbers of lines (and rows), at which
C                    the blocks finish
      INTEGER I1,I2
      EXTERNAL IND
      INTEGER IND
C-----------------------------------------------------------------------
C     Initiating first block:
      NB=1
      IB(0)=0
      IB(1)=1
      I1=0
  10  CONTINUE
C       Loop for lines of the matrix:
        I1=I1+1
        DO 20, I2=N,IB(NB)+1,-1
C         Loop for rows of the line I1:
          IF (SM(IND(I1,I2)).NE.0.) THEN
C           The block is larger:
            IB(NB)=I2
            GOTO 21
          ENDIF
  20    CONTINUE
  21    CONTINUE
        IF (IB(NB).EQ.N) THEN
C         End of the search for blocks.
          RETURN
        ENDIF
        IF (IB(NB).EQ.I1) THEN
C         Block finished, continuing with the next block.
          NB=NB+1
          IB(NB)=I1+1
        ENDIF
      GOTO 10
      END
C=======================================================================
      INTEGER FUNCTION IND(I,J)
      INTEGER I,J
C     I ... Index of a line.
C     J ... Index of a row.
      IND=J*(J-1)/2+I
      RETURN
      END
C
C=======================================================================
C
      INCLUDE 'error.for'
C     <A HREF="../forms/error.for" TYPE="text/html">error.for</A>
      INCLUDE 'sep.for'
C     <A HREF="../forms/sep.for" TYPE="text/html">sep.for</A>
      INCLUDE 'forms.for'
C     <A HREF="../forms/forms.for" TYPE="text/html">forms.for</A>
      INCLUDE 'length.for'
C     <A HREF="../forms/length.for" TYPE="text/html">length.for</A>
      INCLUDE 'mat.for'
C     <A HREF="../forms/mat.for" TYPE="text/html">mat.for</A>
      INCLUDE 'indexi.for'
C     <A HREF="../general.htm#NR">indexi.for</A>
      INCLUDE 'eigennr.for'
C     <A HREF="../forms/eigennr.for" TYPE="text/html">eigennr.for</A>
      INCLUDE 'indexx.for'
C     <A HREF="../general.htm#NR">indexx.for of Numerical Recipes</A>
      INCLUDE 'tred2.for'
C     <A HREF="../general.htm#NR">tred2.for of Numerical Recipes</A>
      INCLUDE 'tqli.for'
C     <A HREF="../general.htm#NR">tqli.for of Numerical Recipes</A>
      INCLUDE 'pythag.for'
C     <A HREF="../general.htm#NR">pythag.for of Numerical Recipes</A>
C
C=======================================================================
C                                                                 </PRE>
